Adresse der letzten Zelle in Zellbereich

Überblick

Um die Adresse der ersten Zelle in einem Zellbereich zu ermitteln, benötigen wir eine Formel auf Basis der ADRESSE-Funktion oder ZELLE-Funktion

Formel

=ADRESSE(ZEILE(A4:C9)+ZEILEN(A4:C9)-1;SPALTE(A4:C9)+SPALTEN(A4:C9)-1) alternativ
=ZELLE("adresse";INDEX(A4:C9;ZEILEN(A4:C9);SPALTEN(A4:C9)))

Funktionsweise der Formel mit ADRESSE

1) Die ADRESSE-Funktion benötigt eine Zeilen- und Spaltennummer um die Adresse des Zellbezugs auszugeben.

ADRESSE(1,1) wäre z.B. die Adresse der ersten Zeile und der ersten Spalte = $A$1.

2) Diese Zeilen- und Spaltennummer der Zelle die sich oben Links in dem Zellbereich befindet, ermitteln wir mit Hilfe der ZEILE bzw. SPALTE-Funktion und dem Zellbereich.

ZEILE(A4:C9) gibt uns die Zeilennummer der ersten Zeile im Zellbereich, also = 4
SPALTE(A4:C9) gibt uns die Spaltennummer der ersten Spalte im Zellbereich, also = 1

3) Anschließend müssen wir noch die Anzahl der Zeilen und Spalten in dem Zellbereich addieren um somit die Position der letzten Zelle im Zellbereich zu ermitteln. Dazu verwenden wir die ZEILEN-Funktion bzw. SPALTEN-Funktion.
ZEILE(A4:C9) + ZEILEN(A4:C9)-1 = 4 + 6 -1 = 9
SPALTE(A4:C9) + SPALTEN(A4:C9)-1 = 1 + 3 -1 = 3

4) Wenn wir die Formel auflösen ergibt sich:
=ADRESSE(ZEILE(A4:C9)+ZEILEN(A4:C9)-1;SPALTE(A4:C9)+SPALTEN(A4:C9)-1)
=ADRESSE(9;3) = $C$9

Funktionsweise der Formel mit ZELLE

Die ZELLE-Funktion benötigt einen Zellbezugs und gibt automatisch die Adresse der oberen linken Zelle des Zellbereichs aus. 

1) D.h. wir müssen die letzte Zelle unten rechts im Zellbereich an die ZELLE-Funktion übergeben. Diese Zelle bekommen wir mit Hilfe der INDEX-Funktion, ZEILEN-Funktion und SPALTEN-Funktion.
ZEILEN(A4:C9) = 6
SPALTEN(A4:C9) = 3
=INDEX(A4:C9;ZEILEN(A4:C9);SPALTEN(A4:C9))
=INDEX(A4:C9;6;3) gleich 6. Zeile und 3. Spalte in dem Bereich A4:C9
=C9

2) Die Zelle C9 wird als Bezug in Funktion ZELLE übergeben.
=ZELLE("adresse";INDEX(A4:C9;ZEILEN(A4:C9);SPALTEN(A4:C9)))
=ZELLE("adresse";C9)
=$C$9