Summe mit mehreren Kriterien

Um eine Summe auf Grundlage von mehreren Kriterien zu bilden, benötigen wir die SUMMEWENNS-Funktion, die FILTER-Funktion oder die SUMMENPRODUKT-Funktion.

In diesem Beispiel möchten wir die Summe für alle Produkte mit der Farbe Weiß und dem Gewicht von mehr als 15kg ermitteln.

Dazu können wir am besten die SUMMEWENNS-Funktion verwenden.

=SUMMEWENNS(Summe_Bereich; Kriterien_Bereich1; Kriterium1; [Kriterien_Bereich2; Kriterium2]; ...)
=SUMMEWENNS(C4:C10;A4:A10;"Weiß";B4:B10;">15")

• Summe_Bereich ist der Bereich, wo die Werte stehen, die wir aufsummieren möchten (Spalte C).
• Kriterien_Bereich1 ist der Bereich, wo wir nach dem 1. Kriterium (Farbe) schauen (Spalte A).
• Kriterien_Bereich2 ist der Bereich, wo wir nach dem 2. Kriterium (Gewicht) schauen (Spalte B).
• Kriterium1 ist die Farbe "Weiß". Wir können die Kriterien direkt in die Formel schreiben oder per Verweis aus der Zellen E4 und F4 holen.
• Kriterium2 ist das Gewicht größer als 15 Kilogramm ''>15'. Wenn wir mit größer und kleiner Operatoren arbeiten müssen diese in der Formel in Anführungszeichen gesetzt werden.

Mit der neuen FILTER-Funktion lässt sich das gleiche Ergebnis erzielen.

=SUMME(FILTER(Matrix; einschließen; [wenn_leer])
=SUMME(FILTER(C4:C10;(A4:A10="Weiß")*(B4:B10>15)))

• Matrix ist der Bereich, wo die Werte stehen, die wir aufsummieren möchten (Spalte C)
• einschließen beinhaltet sowohl die Kriterien_Bereichen und Kriterien (Spalte B und C). Bei mehreren Kriterienbereich-Kriterium Kombinationen müssen diese in Klammern gesetzt und miteinander multipliziert werden.   
• [wenn_leer] benötigen wir hier nicht

Erklärung

Bei der FILTER-Funktion handelt es sich um eine der neuen Array- bzw. Feld-Funktionen. Diese arbeitet sich zeilenweise vor.

FILTER(C4:C10;(A4:A10="Weiß")*(B4:B10>15))

Der erste Bereich ist A4:A10. Hier prüfen wir ob, die Einträge gleich "Weiß" sind.
Dies geschieht zeilenweise und wenn dies so ist, wird der Wert WAHR bzw. 1.

Das gleiche geschieht auch in dem zweiten Bereich B4:B10.

Im Ergebnis bekommen wir zwei Arrays mit WAHR und FALSCH Werten. Diese multiplizieren wir mit einander und da WAHR gleich 1 und FALSCH gleich 0 ist. Bekommen wir ein Ergebnisarray mit 0, 1 bzw. FALSCH und WAHR Werten. Wenn beide Kriterien WAHR sind, wird WAHR * WAHR bzw. 1 * 1 multipliziert was als wiederum WAHR ergibt. Wenn eine der beiden Seiten FALSCH ist, ist das Ergebnis auch FALSCH.

Wenn beide Kriterien erfüllt sind, wird die Zeile von der FILTER-Funktion ausgegeben. Diese beiden Ergebniszeilen werden dann abschließend noch mit der SUMME-Funktion aufsummiert.
=SUMME(FILTER(C4:C10;(A4:A10="Weiß")*(B4:B10>15)))

Die SUMMENPRODUKT-Funktion geht ähnlich vor wie die FILTER-Funktion. Auch hier werden Arrays miteinander multipliziert. 

=SUMMENPRODUKT(Array1; [Array2]; ...)
=SUMMENPRODUKT((A4:A10="weiß")*(B4:B10>15)*(C4:C10))

• Array sind die Bereiche die zeilenweise multipliziert und dann aufsummiert werden.

Erklärung

Für die Funktion benötigen wir Zahlen, d.h. müssen weiß/blau und die Kilogrammzahlen in 1 und 0 umwandeln. Dies erreichen wir durch den Abgleich mit unserem Kriterium. Wie bei der FILTER-Funktion erhalten wir Arrays mit WAHR und FALSCH Werten. Diese werden hier auch noch zusätzlich mit den Werten aus Spalte C multipliziert und dann aufsummiert.

Es wird also die SUMME aller PRODUKTE gebildet, daher auch der Funktionsname SUMMENPRODUKT.